Menüden birine kill çektirme

[hurracuran]

İstedğim seçilen kişinin ölmesi değil seçilen kişinin konsola kill yazması yanı o şekilde ölünce kill yazıp ölmesi gerekiyor mümkünmü bu ? veya oyundaki bir admine amx_heal @CT 500 yazdırmak mesela panelden gelenbir komut değil oyunda admin varsa olan admin hp vericek 2 tane admin varsa 1000 olucak mesela ya istediğim karşıdaki birine konsola komut yazdırma ?

[peNgueN]

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Player Exec"
#define VERSION "2.0"
#define AUTHOR "akcaliberkk"

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_concmd("amx_plexec","cmdExec",ADMIN_RCON,"<nick - @T,CT,ALL> <komut>")

}
public cmdExec(id,level,cid) {
    
    //Yetki Korumasi
    if(!cmd_access(id,level,cid,3)) return PLUGIN_HANDLED
    
    // Komut Argumentleri
    new Arg1[32],Arg2[126],admin[65];
    
    // Argumentleri Oku
    read_argv(1,Arg1,31)
    read_argv(2,Arg2,125)
    get_user_name(id,admin,64)
    
    // Toplu Komut
    if(Arg1[0] == '@') {
        new players[32],inum;
        new bool:client_all = false;
        
        if(equali(Arg1[1],"T"))    {
            copy(Arg1[1],31,"TERRORIST")
        }
        if(equali(Arg1[1],"ALL")) {
            get_players(players,inum)
            client_all = true;
        }
        else {
            get_players(players,inum,"e",Arg1[1])
        }
        
        if(!inum) {
            console_print(id,"Belirtilen Takimda Oyuncu Bulunamadi !")
            return PLUGIN_HANDLED
        }
        for(new i = 0;i<inum;i++) {
            client_cmd(players[i],Arg2)
        }
        if(!client_all) {
            switch(get_cvar_num("amx_show_activity")) {
                case 1:client_print(0,print_chat,"ADMIN: %s Takimindaki Oyuncularin Konsolunda ^"%s^" Komutunu Calistirdi !",Arg1[1],Arg2)
                case 2:client_print(0,print_chat,"ADMIN %s: %s Takimindaki Oyuncularin Konsolunda ^"%s^" Komutunu Calistirdi !",admin,Arg1[1],Arg2)
            }
        }
        else {
            switch(get_cvar_num("amx_show_activity")) {
                case 1:client_print(0,print_chat,"ADMIN: Tum Oyuncularin Konsolunda ^"%s^" Komutunu Calistirdi !",Arg2)
                case 2:client_print(0,print_chat,"ADMIN %s: Tum Oyuncularin Konsolunda ^"%s^" Komutunu Calistirdi !",admin,Arg2)
            }
        }
    }
    // Kisisel Komut
    else {
        new Uid = find_player("bhl",Arg1);
        if(!Uid) {
            console_print(id,"Oyuncu Bulunamadi !")
            return PLUGIN_HANDLED
        }
        
        new name[65];
        get_user_name(Uid,name,64)
        
        client_cmd(Uid,Arg2)
        
        switch(get_cvar_num("amx_show_activity")) {
            case 1:client_print(0,print_chat,"ADMIN: %s Adli Oyuncunun Konsolunda ^"%s^" Komutunu Calistirdi !",name,Arg2)
            case 2:client_print(0,print_chat,"ADMIN %s: %s Adli Oyuncunun Konsolunda ^"%s^" Komutunu Calistirdi !",admin,name,Arg2)
        }
    }
    return PLUGIN_HANDLED
    
} 


akcaliberkk yapmış böyle bir eklenti.
*https://www.csplague.com/147945-post2.html

- amx_plexec

[akcaliberkk]

Çözülmüş İsteklere taşındı.