Komut yasaklayacı [akcaliberk]

[PhantomRui]

Arkadaşlar merhaba komut yasaklayıcı bir plugin kullanıyorum ancak amx_weapon @all 200 ü kabul etmiyor. Nasıl etmiyor derseniz amx_weapon @all kısmını kabul ediyor 200 ü kabul etmiyor yani herkese silah verme kapanıyor ben sadece 200'ün kapanmasını istiyorum.

Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>


#define PLUGIN "Yasakli Komutlar"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"


#define MAX_YASAK 50


new line;
new dosya[256];
new readdata[32][MAX_YASAK+1]
new pcvar;


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    pcvar = register_cvar("yk_obeyimmunity","0")
    
    LoadFile()
}
public cmdBlockNormal(id) {
    if((get_user_flags(id) & ADMIN_IMMUNITY) && get_pcvar_num(pcvar)) {
        return PLUGIN_CONTINUE
    }
    return PLUGIN_HANDLED
}
public cmdBlockKick(id) {
    if((get_user_flags(id) & ADMIN_IMMUNITY) && get_pcvar_num(pcvar)) {
        return PLUGIN_CONTINUE
    }
    server_cmd("kick #%d ^"Yasakli Komut Sebebiyle Atildiniz^"",get_user_userid(id))
    return PLUGIN_HANDLED
}
public cmdBlockBan(id) {
    if((get_user_flags(id) & ADMIN_IMMUNITY) && get_pcvar_num(pcvar)) {
        return PLUGIN_CONTINUE
    }
    server_cmd("amx_ban #%d 0 ^"Yasakli Komut Sebebiyle Banlandiniz^"",get_user_userid(id))
    return PLUGIN_HANDLED
}
public LoadFile() {
    get_configsdir(dosya,255)
    format(dosya,255,"%s/yasak_listesi.ini",dosya)
    new txtlen;
    for( line = 0;line<=MAX_YASAK;line++) {
        read_file(dosya,line,readdata,31,txtlen)
        new komut[30],metod[2];
        parse(readdata,komut,29,metod,1)
        remove_quotes(komut)
        remove_quotes(metod)
        new imetod = str_to_num(metod);
        switch(imetod) {
            case 1:register_concmd(komut,"cmdBlockNormal")
            case 2:register_concmd(komut,"cmdBlockKick")
            case 3:register_concmd(komut,"cmdBlockBan")
            default:register_concmd(komut,"cmdBlockNormal")
        }
    }
}

[Nefesim]

.ini dosyasından ayarlayabilirsiniz.

[PhantomRui]

.ini dosyasından ayarlandığını zaten biliyorum.. mesajı okursanız ne demek istediğimi anlarsınız

[akcaliberkk]

O plugin sanırım 2 den fazla parametre alamıyordu.

Bunu kullanın:

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Weapon 200 Blocker"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"


public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_concmd("amx_weapon","cmdBlock")
}
public cmdBlock(id) {
    new arg[32],arg2[32];
    read_argv(1,arg,31)
    read_argv(2,arg2,31)
    new num = str_to_num(arg2);
    if(equali(arg,"@all") && num == 200) return PLUGIN_HANDLED
    return PLUGIN_CONTINUE
} 


[PhantomRui]

Çalışıyor teşekkürler

[akcaliberkk]

Çözülmüş İsteklere taşındı.

[Furkan Dize]

Sorunun çözülmüş fakat istersen bir çözümü daha var eğer kendine ait olan amx_super pluginini kullanıyorsan smadan amx_weapon 200 parametresini silebilirsin.