Map başında ekrana renk gelmesi

[HijyeniK]

Öncelikle merhaba.
İstediğim plugin forumda vardı fakat ekrana yazı geliyordu.
İstediğim plugin map başında CT'de olanlara mavi T'de olanlara kırmızı ışık gelecek ekrana (saydam bir ışık)
Bu renk ekranda 3 saniye kalacak sonra gidecek
Şimdiden teşekkürler iyi forumlar herkese.

[к4dανяα]

 #include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "istek plugin"
#define VERSION "1.0"
#define AUTHOR "K4DavRa"


#define FFADE_IN        0x0000        
#define FFADE_OUT            0x0001        
#define FFADE_MODULATE        0x0002        
#define FFADE_STAYOUT        0x0004


enum {
    Red,
    Green,
    Blue
}

new bool:engel = false

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_logevent("Event_Round_Start", 2, "1=Round_Start")
}
public Event_Round_Start()
{
    if(engel) {
        return PLUGIN_HANDLED
    }
    for(new id = 1; id < 33; id++) {
        if(is_user_connected(id) && is_user_alive(id)) {
            set_task(0.5,"Sec",id)
        }
    }
    engel = true
    return PLUGIN_CONTINUE
}

public Sec(id)
{
    if(get_user_team(id) == 1) {
        
        UTIL_ScreenFade(id,{100,0,0},1.0,0.2,255,FFADE_IN,false,false) //kirmizi
    }else { 
        UTIL_ScreenFade(id,{0,0,255},1.0,0.2,255,FFADE_IN,false,false)   //mavi
    }

}

stock UTIL_ScreenFade(id=0,iColor[3]={0,0,0},Float:flFxTime=-1.0,Float:flHoldTime=0.0,iAlpha=0,iFlags=FFADE_IN,bool:bReliable=false,bool:bExternal=false)
{
    if( id && !is_user_connected(id))
        return;
    
    new iFadeTime;
    if( flFxTime == -1.0 )
    {
        iFadeTime = 4;
    }
    else
    {
        iFadeTime = FixedUnsigned16( flFxTime , 1<<12 );
    }
    
    static gmsgScreenFade;
    if( !gmsgScreenFade )
    {
        gmsgScreenFade = get_user_msgid("ScreenFade");
    }
    
    new MSG_DEST;
    if( bReliable )
    {
        MSG_DEST = id ? MSG_ONE : MSG_ALL;
    }
    else
    {
        MSG_DEST = id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST;
    }
    
    if( bExternal )
    {
        emessage_begin( MSG_DEST, gmsgScreenFade, _, id );
        ewrite_short( iFadeTime );
        ewrite_short( FixedUnsigned16( flHoldTime , 1<<12 ) );
        ewrite_short( iFlags );
        ewrite_byte( iColor[Red] );
        ewrite_byte( iColor[Green] );
        ewrite_byte( iColor[Blue] );
        ewrite_byte( iAlpha );
        emessage_end();
    }
    else
    {
        message_begin( MSG_DEST, gmsgScreenFade, _, id );
        write_short( iFadeTime );
        write_short( FixedUnsigned16( flHoldTime , 1<<12 ) );
        write_short( iFlags );
        write_byte( iColor[Red] );
        write_byte( iColor[Green] );
        write_byte( iColor[Blue] );
        write_byte( iAlpha );
        message_end();
    }
}

stock FixedUnsigned16(Float:flValue, iScale)
{
    new iOutput;
    
    iOutput = floatround(flValue * iScale);
    
    if ( iOutput < 0 )
        iOutput = 0;
    
    if ( iOutput > 0xFFFF )
        iOutput = 0xFFFF;
    
    return iOutput;
}