Kabus Plugini

[Nobb]

Merhaba Arkadaşlar Ben Kabus Plugini İstiyorum Başlıkta Belirttiğim Gibi Yani.Şimdiden Cevabınızı Bekliyorum.Şimdiden Teşekkürler...

[sefatokgoz]

Biraz açar mısın ?

[DeaTReX]

Nasıl Birşey Olucak ?

[Nobb]

Kabus modundayken ctler sadece bıçak kullanabiliyor ve 7.000 HPleri oluyor.
Teröristlerin ise 200 HPsi ve Ak47 + Pompalilari var.
Teröristlerin ekranında yoğun kan kırmızısı bir sis var.Bu yüzden uzağı göremiyorlar.
Ctlerde ise aksine sis falan yok.

[akcaliberkk]

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN "Kabus Oyunu"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"

new bool:game_started;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /kabus","cmdKabus")
    
    RegisterHam(Ham_Spawn,"player","fwd_HamPlayerSpawnPost",1)
    register_logevent("e_RoundEnd",2,"1=Round_End")
    register_event("CurWeapon","e_CurWeapon","be","1=1")
    
}
public e_RoundEnd() {
    game_started = false;
    SisYarat( 0, .clear = true )
}
public fwd_HamPlayerSpawnPost(id) {
    if(game_started) {
        if(get_user_team(id) == 2) {
            strip_user_weapons(id)
            give_item(id,"weapon_knife")
            set_user_health(id,7000)
        }
        else if(get_user_team(id) == 1) {
            give_item(id,"weapon_ak47")
            give_item(id,"weapon_m3")
            cs_set_user_bpammo(id,CSW_AK47,90)
            cs_set_user_bpammo(id,CSW_M3,32)
            set_user_health(id,200)
            SisYarat( id, 160, 0, 0, 0.003, false )
        }
    }
}
public e_CurWeapon(id) { 
    if(get_user_team(id) == 2 && get_user_weapon(id) != CSW_KNIFE && game_started) {
        strip_user_weapons(id)
        give_item(id,"weapon_knife")
    }
}
public cmdKabus(id) {
    if(!access(id,ADMIN_BAN)) {
        client_print(id,print_chat,"Yetkin Yok")
        return PLUGIN_HANDLED
    }
    if(game_started) {
        client_print(id,print_chat,"Kabus Oyunu Zaten Acik")
        return PLUGIN_HANDLED
    }
    game_started = true;
    new players[32],inum;
    static tempid;
    get_players(players,inum)
    for(new i;i<inum;i++) {
        tempid = players[i];
        if(get_user_team(tempid) == 2) {
            strip_user_weapons(tempid)
            give_item(tempid,"weapon_knife")
            set_user_health(tempid,7000)
        }
        else if(get_user_team(tempid) == 1) {
            give_item(tempid,"weapon_ak47")
            give_item(tempid,"weapon_m3")
            cs_set_user_bpammo(tempid,CSW_AK47,90)
            cs_set_user_bpammo(tempid,CSW_M3,32)
            set_user_health(tempid,200)
            SisYarat( tempid, 160, 0, 0, 0.003, false )
        }
    }
    new name[32];
    get_user_name(id,name,31)
    client_print(0,print_chat,"Admin %s Kabus Oyununu Baslatti !",name)
    return PLUGIN_HANDLED
}
stock SisYarat ( const index = 0, const red = 127, const green = 127, const blue = 127, const Float:density_f = 0.001, bool:clear = false ) { 
    static msgFog; 
    
    if ( msgFog || ( msgFog = get_user_msgid( "Fog" ) ) ) { 
        new density = _:floatclamp( density_f, 0.0001, 0.25 ) * _:!clear; 
        
        message_begin( index ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, msgFog, .player = index ); 
        write_byte( clamp( red  , 0, 255 ) ); 
        write_byte( clamp( green, 0, 255 ) ); 
        write_byte( clamp( blue , 0, 255 ) ); 
        write_long( _:density ); 
        message_end(); 
    } 
} 


Bilgi vermediğin için, /kabus yazan her ban yetkili admin kabus oyunu başlatabilir şeklinde ayarladım.

[sefatokgoz]

Bunu araştırdım ama 10 tl imiş. Berk sağolsun

[Nobb]

Teşekkürler...

[akcaliberkk]

Çözülmüş İsteklere taşındı.

[OnlyPeach]

Ellerine Sağlık Berk

- - - - - - - - - -

Ellerine Sağlık Berk