PHP- Kodu:
/*    Formatright © 2009, ConnorMcLeod

    Multi Jumps is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with Multi Jumps; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>

#define ADMIN_MULTIJUMP ADMIN_RCON

#define VERSION "0.0.7"

#define MAX_PLAYERS 32

#define m_iTeam 114
#define m_afButtonPressed 246
#define m_flFallVelocity 251

new g_iJumpCount[MAX_PLAYERS+1]
new g_bMultiJump[MAX_PLAYERS+1 char]

new g_pCvarMultiJumps, g_pCvarTeamAllowed, g_pCvarOnlyAdmins, g_pCvarMaxFallVelocity, g_pCvarJumpVelocity

public plugin_init()
{
    register_plugin("Multi Jumps", VERSION, "ConnorMcLeod")

    g_pCvarMultiJumps = register_cvar("mp_multijumps", "1")
    g_pCvarTeamAllowed = register_cvar("mp_multijumps_team", "2") //0:nobody, 1:terrorists, 2:cts, 3:all
    g_pCvarOnlyAdmins = register_cvar("mp_multijumps_adminonly", "0")
    g_pCvarMaxFallVelocity = register_cvar("mp_multijump_maxfallvelocity", "99999999999")
    g_pCvarJumpVelocity = register_cvar("mp_multijumps_jumpvelocity", "333")

    register_clcmd("say /mj", "ClCmd_Say_MultiJump")
    register_clcmd("say /multijump", "ClCmd_Say_MultiJump")

    RegisterHam(Ham_Player_Jump, "player", "OnCBasePlayer_Jump", false)
}

public client_putinserver( id )
{
    g_bMultiJump{ id } = true
}

public ClCmd_Say_MultiJump( id )
{
    client_print(id, print_chat, " * MultiJumps : %sable", ( g_bMultiJump{ id } = !g_bMultiJump{ id } ) ? "en" : "dis")
}

public OnCBasePlayer_Jump(id)
{
    if( !g_bMultiJump{ id } || !is_user_alive(id) )
    {
        return HAM_IGNORED
    }

    new fFlags = pev(id, pev_flags)
    if(    fFlags & FL_WATERJUMP
    ||    pev(id, pev_waterlevel) >= 2
    ||    !(get_pdata_int(id, m_afButtonPressed) & IN_JUMP)    )
    {
        return HAM_IGNORED
    }

    if(    fFlags & FL_ONGROUND    )
    {
        g_iJumpCount[id] = 0
        return HAM_IGNORED
    }

    new iMulti = get_pcvar_num(g_pCvarMultiJumps)

    if( iMulti )
    {
        if(    get_pcvar_num(g_pCvarTeamAllowed) & get_pdata_int(id, m_iTeam)
        ||    ( get_pcvar_num(g_pCvarOnlyAdmins) && get_user_flags(id) & ADMIN_MULTIJUMP )    )
        {
            if(    get_pdata_float(id, m_flFallVelocity) < get_pcvar_float(g_pCvarMaxFallVelocity)
            &&    ++g_iJumpCount[id] <= iMulti    )
            {
                new Float:fVelocity[3]
                pev(id, pev_velocity, fVelocity)
                fVelocity[2] = get_pcvar_float(g_pCvarJumpVelocity)
                set_pev(id, pev_velocity, fVelocity)
                return HAM_HANDLED
            }
        }
    }

    return HAM_IGNORED
} 
Bir teşekkürü çok görmeyiniz [Alıntıdır ]