HP menu

[DeadNight26]

Aynn bende error vermişti bi gözden geçirdim sorun ;; şeklinde yapmış

 if( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;;
    }
    new Data[ 24 ], Name[ 64 ]; 
  

---->

 if( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;
    }
    new Data[ 24 ], Name[ 64 ]; 
  

tam olarak sma böyle yapınca bende oldu

 /* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "HP Menu"
#define VERSION "1.0"
#define AUTHOR "peNgueN"

new Hp_Secenek;

new Oyuncu[ 33 ];

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    register_clcmd( "say /hpvermenu", "Hp_Menu", ADMIN_KICK );
    register_clcmd( "Hp_Ver", "Verilecek_Hp" );
}

public Hp_Menu( id )
{
    new menu = menu_create( "\yHP MENU", "HPMenuHandler" );
    
    menu_additem( menu, "\rCT\w'ye HP Ver", "1", 0 );
    menu_additem( menu, "\rT\w'ye HP Ver", "2", 0 );
    menu_additem( menu, "\yHP Verilecek Kisi Sec", "3", 0 );
    menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
    menu_display(id, menu);
    return PLUGIN_HANDLED;
}

public HPMenuHandler( id, menu, item )
{
    if(item == MENU_EXIT)
    {
        menu_destroy(menu);
        return PLUGIN_HANDLED;
    }
    
    new Data[ 24 ], Name[ 64 ];
    new Access, callback;
    
    menu_item_getinfo( menu, item, Access, Data, charsmax( Data ), Name, charsmax( Name ), callback );
    
    new key = str_to_num( Data );
    
    switch( key )
    {
        case 1:
        {
            client_cmd( id, "messagemode Hp_Ver" );
            client_print( id, print_chat, "CT' ye HP Verin." );
            Hp_Secenek = 1;
        }
        case 2:
        {
            client_cmd( id, "messagemode Hp_Ver" );
            client_print( id, print_chat, "T' ye HP Verin." );
            Hp_Secenek = 2;
        }
        case 3:
        {
            HPVer( id );
        }
    }
    menu_destroy( menu );
    return PLUGIN_HANDLED;
}

public HPVer( id )
{
    new menu[64], iMenu;
    new oyuncular[ 32 ], onum;
    new isim[ 64 ], sira[ 10 ];
    
    get_players( oyuncular, onum, "a" );
    
    formatex( menu, charsmax( menu ), "\yHP Vermek icin Oyuncu Secin", LANG_PLAYER );
    iMenu = menu_create( menu, "HPVerDevam" );
    
    for( new i; i < onum ; i++ )
    {
        get_user_name( oyuncular[ i ], isim, charsmax( isim ) );
        num_to_str( oyuncular[ i ], sira, 9);
        
        formatex( menu, charsmax( menu ), "\y- %s - %d CAN", isim, get_user_health( oyuncular[ i ] ) );
        menu_additem( iMenu, menu, sira, 0 );
    }
    
    menu_display( id, iMenu);
    return PLUGIN_HANDLED;    
}

public HPVerDevam( id, menu, item )
{
    if( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;
    }
    new Data[ 24 ], Name[ 64 ];
    new Access, callback;
    menu_item_getinfo( menu, item, Access, Data, charsmax( Data ), Name, charsmax( Name ), callback );
    
    new tempid = str_to_num( Data );
    
    new name[ 64 ];
    get_user_name( tempid, name, charsmax( name ) );
    //
    Hp_Secenek = 3;
    Oyuncu[ id ] = tempid;
    client_print( id, print_chat, "%s isimli oyuncuya hp ver.", name );
    client_cmd( id, "messagemode Hp_Ver" );
    //
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

public Verilecek_Hp( id )
{
    new say[ 300 ];
    read_args( say, charsmax( say ) );
    
    remove_quotes( say );
    
    if( !is_str_num( say ) || equal( say, "" ) || strlen(say) > 5 )
        return PLUGIN_HANDLED;
    
    new iOyuncu = Oyuncu[ id ];
    new miktar  = str_to_num( say );
    
    switch( Hp_Secenek )
    {
        case 1:
        {
            new oyuncular[ 32 ], onum;
            get_players( oyuncular, onum, "ae", "CT" );
            
            for( new i; i < onum; i++ )
            {
                set_user_health( oyuncular[ i ], get_user_health( oyuncular[ i ] ) + miktar );
            }
            client_print( id, print_chat, "CT' ye %d HP Verildi..", miktar );
        }
        case 2:
        {
            new oyuncular[ 32 ], onum;
            get_players( oyuncular, onum, "ae", "TERRORIST" );
            
            for( new i; i < onum; i++ )
            {
                set_user_health( oyuncular[ i ], get_user_health( oyuncular[ i ] ) + miktar );
            }
            client_print( id, print_chat, "T' ye %d HP Verildi..", miktar );
        }
        case 3: 
        {
            new oyuncuname[ 64 ];
            get_user_name( iOyuncu, oyuncuname, charsmax( oyuncuname ) );
            
            set_user_health( iOyuncu, get_user_health( iOyuncu ) + miktar );
            client_print( id, print_chat, "%s isimli oyuncuya %d HP verildi..", oyuncuname, miktar );
        }
    }
    return PLUGIN_HANDLED;
}