amx_sxebanmenu

[akcaliberkk]

 /* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "SxeBanMenu"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"

#define ADMIN_FLAG ADMIN_RCON

new target[33];

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("amx_sxebanmenu","cmdSxeBanMenu")
    register_clcmd("say /sxebanmenu","cmdSxeBanMenu")
    
    if(!cvar_exists("__sxei_required")) {
        set_fail_state("Bu plugini kullanabilmek icin Sxe Injected kurmalisiniz")
    }
}
public cmdSxeBanMenu(id,level,cid) {
    if(!access(id,ADMIN_FLAG)) {
        console_print(id,"Yetkiniz yok")
        client_print(id,print_chat,"[sXe] Yetkiniz yok")
        return PLUGIN_HANDLED
    }
    
    new players[32],inum;
    get_players(players,inum)
    static tempid,name[32],szID[6];
    new menu = menu_create("\r[sXe] \ySxe Ban Menu ^nOyuncu Secin","cmdSxeBanMenuHandle")
    for(new i; i<inum; i++) {
        tempid = players[i]
        get_user_name(tempid,name,31)
        num_to_str(tempid,szID,5)
        menu_additem(menu,name,szID)
    }
    menu_display(id,menu)
    return PLUGIN_HANDLED
}
public cmdSxeBanMenuHandle(id,menu,item) {
    if(item == MENU_EXIT) {
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    new name[32],szID[6],callback,access;
    menu_item_getinfo(menu,item,access,szID,5,name,31,callback)
    new tempid = str_to_num(szID)
    if(!is_user_connected(tempid)) {
        client_print(id,print_chat,"[sXe] Ilgili oyuncu bagli degil !")
        return PLUGIN_HANDLED
    }
    target[id] = tempid;
    ConfirmMenu(id)
    return PLUGIN_HANDLED
}
public ConfirmMenu(id) {
    new name[32]; get_user_name(target[id],name,31)
    new text[128]; 
    formatex(text,127,"\r[sXe] \ySxe Ban Menu ^n\r%s \yAdli \
    Oyuncuyu Banlamak Uzeresiniz.^n Devam etmek istediginize emin misiniz ?",name)
    new menu = menu_create(text,"ConfirmMenuHandle")
    
    menu_additem(menu,"Devam Et","")
    menu_additem(menu,"\rIptal","")
    
    menu_setprop(menu,MPROP_EXIT,MEXIT_NEVER)
    menu_display(id,menu)
    return PLUGIN_HANDLED
}
public ConfirmMenuHandle(id,menu,item) {
    if(!is_user_connected(target[id])) {
        client_print(id,print_chat,"[sXe] Ilgili oyuncu bagli degil !")
        menu_destroy(menu)
        return PLUGIN_HANDLED
    }
    switch(item) {
        case 1: {
            target[id] = 0;
        }
        case 0: {
            server_cmd("sxe_ban #%d",get_user_userid(target[id]))
            new name[32],tname[32];
            get_user_name(id,name,31)
            get_user_name(target[id],tname,31)
            client_print(0,print_chat,"[sXe] ADMIN %s Sxe Ban: %s",name,tname)
        }
    }
    menu_destroy(menu)
    return PLUGIN_HANDLED
} 
  

EDIT: Sayfayi güncellemeyeli 1 saat olmuş kusura bakma penguen görmedim cevap attığını