el başı bilgi yarısması plugini

[wolf5094]

Arkadaşlar her el başı belirleyeceğimiz 360 sorudan rastgele bir soru gelsin ve sorunun cevabını say dan
1. yazana 5 jb,
2. yazana 3 jb,
3. yazana da 1 jb versin.
daha sonra yazana da malesef soruyu cevaplamakta diğer arkadaşların daha hızlı davrandı gibi bir mesaj gelsin.
bu soruyu cevaplama suresi de 20 saniye olsun.böyle bir plugin yapabilir misiniz yada yapmama yardımcı olabilir misiniz

[akcaliberkk]

Yapılabilir ama pek tutacağını sanmam, yinede istiyorsan yaparım ?

[wolf5094]

tutulur fena olmaz yani sv de yaparsan sevinirim

[akcaliberkk]

Bir dene bakalım

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <colorchat>
#include <jail>

#define PLUGIN "Bilgi Yarsimasi"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"

new const file[] = "addons/amxmodx/configs/sorular.ini";
new gCevap[124];
new bool:bildi[33];
new bool:game_started,bool:first,bool:second,bool:third;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_logevent("eRS",2,"1=Round_Start")
    register_logevent("eRE",2,"1=Round_End")
    
    register_clcmd("say","HookSay")
    register_clcmd("say_team","HookSay")
    
    if(!file_exists(file)) {
        new f = fopen(file,"wt");
        fclose(f);
    }
    
}
public eRS() {
    gCevap[0] = 0;
    set_task(15.0,"OyunBaslat",456123336)
}
public eRE() {
    remove_task(456123336)
    game_started = false;
    new players[32],inum;
    get_players(players,inum)
    for(new i;i<inum;i++) {
        bildi[players[i]] = false;
    }
}
public OyunBaslat() {
    new szLine[248],txtlen,maxlines,szSoru[124],szCevap[124];
    maxlines = file_size(file,1)
    read_file(file,random_num(0,maxlines),szLine,247,txtlen)
    parse(szLine,szSoru,123,szCevap,123)
    copy(gCevap,123,szCevap)
    game_started = true;
    first = true;
    second = true;
    third = true;
    ColorChat(0,GREEN,"[BILGI YARISMASI] Sorunun Cevabini Bilen Ilk 3 Kisiye Odul JB [BILGI YARISMASI]")
    ColorChat(0,GREEN,"SORU: ^3%s",szSoru)
    ColorChat(0,GREEN,"[BILGI YARISMASI] ------------------------------------------- [BILGI YARISMASI]")
    set_task(20.0,"SureBitir",456123336)
    return PLUGIN_HANDLED
}
public HookSay(id) {
    if(!game_started) return PLUGIN_CONTINUE
    
    new szSaid[124],name[32];
    read_args(szSaid,123)
    remove_quotes(szSaid)
    get_user_name(id,name,31)
    if(equali(szSaid,gCevap)) {
        if(bildi[id]) {
            ColorChat(id,GREEN,"[BILGI YARISMASI] ^3Cevabi Zaten Buldunuz !")
            return PLUGIN_HANDLED
        }
        if(first) {
            jb_set_user_packs(id,jb_get_user_packs(id) + 5)
            ColorChat(id,GREEN,"[BILGI YARISMASI] ^3Tebrikler, Birinci Oldunuz ve ^4 5 JB ^3Kazandiniz.")
            ColorChat(0,GREEN,"[BILGI YARISMASI] ^3%s ^1Adli Oyuncu ^4Birinci ^1Bildi.",name)
            first = false;
            bildi[id] = true;
            return PLUGIN_HANDLED
        }
        if(second) {
            jb_set_user_packs(id,jb_get_user_packs(id) + 3)
            ColorChat(id,GREEN,"[BILGI YARISMASI] ^3Tebrikler, Ikinci Oldunuz ve ^4 3 JB ^3Kazandiniz.")
            ColorChat(0,GREEN,"[BILGI YARISMASI] ^3%s ^1Adli Oyuncu ^4Ikinci ^1Bildi.",name)
            second = false;
            bildi[id] = true;
            return PLUGIN_HANDLED
        }
        if(third) {
            jb_set_user_packs(id,jb_get_user_packs(id) + 1)
            ColorChat(id,GREEN,"[BILGI YARISMASI] ^3Tebrikler, Ucuncu Oldunuz ve ^4 1 JB ^3Kazandiniz.")
            ColorChat(0,GREEN,"[BILGI YARISMASI] ^3%s ^1Adli Oyuncu ^4Ucuncu ^1Bildi.",name)
            third = false;
            bildi[id] = true;
            return PLUGIN_HANDLED
        }
        ColorChat(id,GREEN,"[BILGI YARISMASI] ^3Malesef Cevabi Yazmakta Gec Kaldiniz.")
        return PLUGIN_HANDLED
    }
    return PLUGIN_CONTINUE
}
public SureBitir() {
    game_started = false;
    ColorChat(0,GREEN,"[BILGI YARISMASI] ^3Sure DOLMUSTUR. Dogru Cevap : %s",gCevap)
    return PLUGIN_HANDLED
} 


sorular.ini dosyasının içeriği şu şekilde olucak:

"Soru 1" "Cevap 1"
"Soru 2" "Cevap 2"
...[/i]

[wolf5094]

malesef olmadı :S
sorular.ini dosyasını configs içine attım.
sorular ini içerisine de
"abc" "123"
"asd" "321"
yazdım ama soru el başında çıkmadı

[akcaliberkk]

el başladıktan 15 saniye sonra çıkacak şekilde ayarladım ? 15 saniye bekledin mi ?

[wolf5094]

3dakika bekledim malesef olmuyor

[akcaliberkk]

Plugin çalışıyor. Sende bulunan jail modu "jb_set_user_packs" fonksiyonunu desteklemiyor.

JB Pack pluginini paylaşırsan onun içine eklerim. Ancak o zaman çalışır sende

[wolf5094]

Saat gibi çalışıyor eline emegine saglık çok teşekkür ederim.
Konu çözümlenmiştir...

[akcaliberkk]

Çözülmüş İsteklere taşındı.