Hudmessage Değişken Tanımlama

[akcaliberkk]

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Geri Sayim Sayaci"
#define VERSION "1.0"
#define AUTHOR "akcaliberkk"

new is_plugin_request[33];
new bool:is_counting;
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /kronometre","GetStartTime")
    register_clcmd("Saniye","ReceiveStartTime")
}
public GetStartTime(id) {
    is_plugin_request[id] = true;
    client_cmd(id,"messagemode Saniye")
}
public ReceiveStartTime(id) {
    if(!is_plugin_request[id]) {
        console_print(id,"Gecersiz Istek")
        return PLUGIN_HANDLED
    }
    new szSaniye[6];
    read_args(szSaniye, charsmax(szSaniye))
    remove_quotes(szSaniye)
    if(!szSaniye[0]) {
        client_print(id, print_chat, "Bos Birakamazsiniz !")
        client_cmd(id,"messagemode Saniye")
        return PLUGIN_HANDLED
    }
    new iSaniye = str_to_num(szSaniye);
    if(iSaniye < 1) {
        client_print(id, print_chat, "Pozitif Bir Tamsayi Girmelisiniz.")
        client_cmd(id,"messagemode Saniye")
        return PLUGIN_HANDLED
    }
    is_plugin_request[id] = false;
    if(is_counting) {
        client_print(id, print_chat, "Suanda Zaten Bir Geri Sayim Aktif.")
        return PLUGIN_HANDLED
    }
    is_counting = true;
    StartCountDown(iSaniye)
    return PLUGIN_HANDLED
}
public StartCountDown(sure) {
    set_hudmessage(255, 170, 0, -1.0, -1.0, 0, 1.0, 1.0)
    if(!sure) {
        show_hudmessage(0,"Geri Sayim Doldu !")
        is_counting = false;
        return PLUGIN_HANDLED
    }
    show_hudmessage(0,"Geri Sayim: %d Saniye",sure)
    sure--
    set_task(1.0,"StartCountDown",sure)
    return PLUGIN_CONTINUE
} 


tam olarak istediğin şey sanırım

is_plugin_request değişkeni ne için diye sorabilirsin, söyleyeyim;

Konsola Saniye diye bir komut kaydettiğimiz için, konsola Saniye 10 yazarsak geri saymaya başlayacaktır. Fakat biz sadece say'dan yazılan kod ile çalışmasını istiyoruz.
Bu değişken ile kişi sayacı başlatmak için /kronometre komutunu kullandı mı kullanmadı mı ayırt edebiliyoruz. Özellikle banka, şifre vs içeren pluginlerde güvenlik ve bug oluşmaması açısından bunu yapmak son derece faydalıdır. Oyuncu komutu konsoldan tetiklemeye çalıştığı zaman "Geçersiz İstek" şeklinde bir uyarı ile karşılaşıcaktır.