Gelismis Gardiyanmenu

[peNgueN]

Buyur Yaptım Eksik Varsa Söyle Tamamlarım.

 /* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <cstrike>
#include <hamsandwich>
#include <jail>

#define PLUGIN "Gelismis Gardiyan Menusu"
#define VERSION "1.0"
#define AUTHOR "peNgueN"

#define CTHP 5000 //Ctlerin Canı 
#define BOMBA 50 //Gelecek Bomba Sayısı
#define MAXJB 1500 // Verilecek En Fazla Jb
#define ADMIN_YETKI ADMIN_BAN // Menuyu Açmak İçin Gerekli Yetki

enum MENULER {
    
    MENU_GARDIYAN,
    MENU_JBVER,
    MENU_REVLE,
    MENU_UNDEFINED    
}

new MENULER: menum = MENU_UNDEFINED;

new bomba[ 33 ];
new bombam[ 33 ];

new jb[ 33 ];

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_logevent( "logevent_roundbaslat", 2, "1=Round_Start");
    
    register_clcmd("say /menu", "GardiyanMenu", ADMIN_YETKI );
    register_clcmd( "say_team /menu", "GardiyanMenu", ADMIN_YETKI );
    
    register_clcmd( "JB", "JBVerSay" );
}
public logevent_roundbaslat(id)
{
    
    new oyuncular[ 32 ], onum;
    get_players( oyuncular, onum, "ae", "CT" );
    
    for(new i; i < onum; i++)
    {
        if( cs_get_user_team( oyuncular[ i ] ) == CS_TEAM_CT )
        {
            bomba[ oyuncular[ i ] ] = 0;
            bombam[ oyuncular[ i ] ] = 0;
            set_user_godmode( oyuncular[ i ], 0 );
        }
    }
}
public BombaVer(task)
{
    new id = task - 1453;
    
    if( is_user_alive( id ) )
    {
        if( bomba[ id ] == 1 )
        {
            if( bombam[ id ] <= BOMBA )
            {
                if(!user_has_weapon(id , CSW_HEGRENADE))
                {
                    give_item(id , "weapon_hegrenade");
                    bombam[ id ]++;
                }
            }
            else
            {
                bomba[ id ] = 0;
                bombam[ id ] = 0;
                client_print( id, print_center, "[JB] Bombaniz Bitti.." );
                remove_task( id + 1453 );
            }
        }
    }
}

public GardiyanMenu( id )
{
    if( cs_get_user_team( id ) == CS_TEAM_CT )
    {
        if( !is_user_alive( id ) )
            return PLUGIN_HANDLED;
        
        new menu[64];
        format( menu, charsmax( menu ), "\y=> \rGelismis Gardiyan Menü \y<=", LANG_PLAYER );
        new iMenu = menu_create( menu, "MenuDevam" );
        
        formatex( menu, charsmax( menu ), "\wYerime Gardiyan Sec");
        menu_additem( iMenu, menu, "1", 0 );
        formatex( menu, charsmax( menu ), "\wCT GodMode + %d HP", CTHP);
        menu_additem( iMenu, menu, "2", 0 );
        formatex( menu, charsmax( menu ), "\wC4 Oynat");
        menu_additem( iMenu, menu, "3", 0 );
        formatex( menu, charsmax( menu ), "\w%d Hegranade", BOMBA);
        menu_additem( iMenu, menu, "4", 0 );
        formatex( menu, charsmax( menu ), "\wÖlü Oyunculari Revle");
        menu_additem( iMenu, menu, "5", 0 );
        formatex( menu, charsmax( menu ), "\wJB \rVer");
        menu_additem( iMenu, menu, "6", 0 );
        menu_display( id, iMenu );
        return PLUGIN_HANDLED;
    }
    return PLUGIN_HANDLED;
}

public MenuDevam( id, menu, item )
{
    if ( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;
    }
    new data[6], name[64];
    new Access, Callback;
    menu_item_getinfo(menu, item, Access, data,5, name, 63, Callback);
    new key = str_to_num(data);
    
    switch (key)
    {
        case 1: 
        {
            menum = MENU_GARDIYAN;
            TMenu(id);
        }
        case 2:
        {
            new oyuncular[32], onum;
            get_players( oyuncular, onum, "ae", "CT" );
            
            for(new i; i < onum; i++)
            {
                set_user_godmode( oyuncular[ i ], 1 );
                set_user_health( oyuncular[ i ], get_user_health( oyuncular[ i ] ) + CTHP );
                client_print( oyuncular[ i ], print_chat, "[JB] GodMode + %d HP Aldiniz..", CTHP );
            }
        }
        case 3:
        {
            C4Sor(id);
        }
        case 4:
        {
            new oyuncular[ 32 ], onum;
            get_players( oyuncular, onum, "ae", "CT" );
            
            for(new i; i < onum; i++)
            {
                if( bomba[ oyuncular[ i ] ] == 1 )
                {
                    client_print( id, print_chat, "[JB] CT Zaten %d Tane Bombaya Sahip..", BOMBA );
                    return PLUGIN_HANDLED;
                }
                else if( bomba[ oyuncular[ i ] ] == 0 )
                {
                    bombam[ oyuncular[ i ] ] = 0;
                    bomba[ oyuncular[ i ] ] = 1;
                    client_print( id, print_chat, "[JB] CT'ye %d Tane Bomba Verdiniz..", BOMBA );
                    set_task(0.3 , "BombaVer" , oyuncular[ i ] + 1453 , _ , _ , "b");
                }
                
            }
        }
        case 5: 
        {
            menum = MENU_REVLE;
            TMenu(id);
        }
        case 6:
        {
            menum = MENU_JBVER;
            TMenu(id);
        }
    }
    menu_destroy(menu);
    return 0;
}

public TMenu(id)
{
    new menu[64], iMenu;
    new oyuncular[ 32 ], onum;
    new isim[ 64 ], sira[ 10 ];
    
    get_players( oyuncular, onum, "e", "TERRORIST" );
    
    switch( menum )
    {
        case MENU_GARDIYAN:
        {
            format( menu, charsmax( menu ), "\yYerine Gardiyan Sec", LANG_PLAYER );
            iMenu = menu_create( menu, "MenuGardiyan" );
            
            for( new i; i < onum ; i++ )
            {
                get_user_name( oyuncular[ i ], isim, charsmax( isim ) );
                num_to_str( oyuncular[ i ], sira, 9);
                
                formatex( menu, charsmax( menu ), "\y- %s", isim );
                menu_additem( iMenu, menu, sira, 0 );
            }
        }
        case MENU_JBVER:
        {
            format( menu, charsmax( menu ), "\wJB \yVer", LANG_PLAYER );
            iMenu = menu_create( menu, "MenuJBVer" );
            
            for( new i; i < onum ; i++ )
            {
                get_user_name( oyuncular[ i ], isim, charsmax( isim ) );
                num_to_str( oyuncular[ i ], sira, 9);
                
                formatex( menu, charsmax( menu ), "\y- %s - \r[ %d ]", isim, jb_get_user_packs( oyuncular[ i ] ) );
                menu_additem( iMenu, menu, sira, 0 );
            }
        }
        case MENU_REVLE:
        {
            new ioyuncular[ 32 ], ionum;
            get_players( ioyuncular, ionum, "be", "TERRORIST" );
            
            format( menu, charsmax( menu ), "\yOyuncu Revle", LANG_PLAYER );
            iMenu = menu_create( menu, "MenuRevle" );
            
            for( new i; i < ionum ; i++ )
            {
                if( !is_user_alive( ioyuncular[ i ] ) )
                {
                    get_user_name( ioyuncular[ i ], isim, charsmax( isim ) );
                    num_to_str( ioyuncular[ i ], sira, 9);
                    
                    formatex( menu, charsmax( menu ), "\y- %s", isim );
                    menu_additem( iMenu, menu, sira, 0 );
                }
            }
        }
    }
    
    menu_display( id, iMenu );
    return PLUGIN_HANDLED;
    
}

public MenuGardiyan( id, menu, item )
{
    
    if( item == MENU_EXIT )
    {
        menu_destroy(menu);
        return 0;
    }
    new Data[6], Name[64];
    new Access, Callback;
    menu_item_getinfo(menu, item, Access, Data,5, Name, 63, Callback);
    new gardiyan = str_to_num(Data);
    
    if( cs_get_user_team( gardiyan ) == CS_TEAM_T )
    {
        if(!is_user_alive( id ))
        {
            cs_set_user_team( gardiyan, CS_TEAM_CT );
            ExecuteHamB(Ham_CS_RoundRespawn, gardiyan);
        }
        else
        {
            cs_set_user_team( gardiyan, CS_TEAM_CT );
        }
        new gisim[ 64 ];
        get_user_name( gardiyan, gisim, charsmax( gisim ) );
        client_print( 0, print_chat, "[JB] %s Gardiyan Oldu..", gisim );
    }
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

public MenuRevle( id, menu, item )
{
    
    if( item == MENU_EXIT )
    {
        menu_destroy(menu);
        return 0;
    }
    new Data[6], Name[64];
    new Access, Callback;
    menu_item_getinfo(menu, item, Access, Data,5, Name, 63, Callback);
    new oyuncu = str_to_num(Data);
    
    if( !is_user_alive( oyuncu ) )
    {
        ExecuteHamB( Ham_CS_RoundRespawn, oyuncu );
        client_print( oyuncu, print_center, "[JB] Yeniden Hayattasin !" );
    }
    else
    {
        client_print( id, print_chat, "[JB] Oyuncu Zaten Canli.." );
        return PLUGIN_HANDLED;
    }
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}

public MenuJBVer( id, menu, item )
{
    
    if( item == MENU_EXIT )
    {
        menu_destroy(menu);
        return 0;
    }
    new Data[6], Name[64];
    new Access, Callback;
    menu_item_getinfo(menu, item, Access, Data,5, Name, 63, Callback);
    new oyuncu = str_to_num(Data);
    jb[ id ] = oyuncu;
    client_cmd( id, "messagemode JB" );
    
    menu_destroy(menu);
    return PLUGIN_HANDLED;
}


public JBVerSay(id)
{
    new say[ 300 ]
    read_args( say, charsmax( say ) )
    
    remove_quotes(say);
    
    if( !is_str_num( say ) || equal( say, "" ) )
        return PLUGIN_HANDLED;
    
    jbver( id, say );    
    
    return PLUGIN_CONTINUE
}

jbver( id, say[] ) 
{
    new miktar = str_to_num( say );
    new oyuncu = jb[ id ];
    
    new oyuncuisim[ 64 ];
    new adminisim[ 64 ];
    
    if(oyuncu > 0)
    {
        get_user_name( oyuncu, oyuncuisim, charsmax( oyuncuisim ) );
        get_user_name( id, adminisim, charsmax( adminisim ) );
        
        if(miktar <= MAXJB)
        {
            jb_set_user_packs( oyuncu, jb_get_user_packs( oyuncu ) + miktar );
        }
        else
        {
            client_print( id, print_chat, "[JB] En Fazla %d JB Verebilme Hakkiniz Var !", MAXJB );
            return PLUGIN_HANDLED;
        }
        client_print( 0, print_chat, "Admin [ %s ], [ %s ] isimli oyuncuya %d JB Verdi",adminisim, oyuncuisim, miktar );
    }
    
    return PLUGIN_HANDLED
}  

public C4Sor(id)
{
    new menu = menu_create( "\wC4 Menu","C4Devam" );
    menu_additem( menu ,"\yGom", "1" );
    menu_additem( menu, "\yNormal", "2" );
    menu_display( id, menu );
    return PLUGIN_HANDLED;
}

public C4Devam( id, menu, item )
{
    if ( item == MENU_EXIT )
    {
        menu_destroy( menu );
        return PLUGIN_HANDLED;
    }
    new data[6], name[64];
    new Access, Callback;
    menu_item_getinfo(menu, item, Access, data,5, name, 63, Callback);
    new key = str_to_num(data);
    
    switch (key)
    {
        case 1: 
        {
            new oyuncular[ 32 ], onum;
            get_players( oyuncular, onum, "ae", "TERRORIST" );
            
            for( new i ; i < onum ; i++ )
            {
                client_cmd( id, "amx_weapon @T c4" );
                engclient_cmd( oyuncular[ i ], "item_c4" );
                client_print( 0, print_chat, "[JB] C4 Oyunu Basladi.." );
            }
            client_cmd( id, "amx_bury @T 1" );
        }
        case 2:
        {
            new oyuncular[ 32 ], onum;
            get_players( oyuncular, onum, "ae", "TERRORIST" );
            
            for( new i ; i < onum ; i++ )
            {
                client_cmd( id, "amx_weapon @T c4" );
                engclient_cmd( oyuncular[ i ], "item_c4" );
                client_print( 0, print_chat, "[JB] C4 Oyunu Basladi.." );
            }
        }
    }
    menu_destroy( menu );
    return PLUGIN_HANDLED;
}